# $Id$
# Maintainer: Qurban Ullah <qurbanullah@avouch.org>
# Contributor: Qurban Ullah <qurbanullah@avouch.org>

pkgname=xf86-video-intel
pkgver=2.99.917+796+g04b4f3b7
pkgrel=1
arch=(i686 x86_64)
url="https://01.org/linuxgraphics"
license=('custom')
install=$pkgname.install
pkgdesc="X.org Intel i810/i830/i915/945G/G965+ video drivers"
depends=('mesa-dri' 'libxvmc' 'pixman' 'xcb-util>=0.3.9' 'libsystemd')
makedepends=('xorg-server-devel' 'X-ABI-VIDEODRV_VERSION=23' 'libx11' 'libxrender'
             # additional deps for intel-virtual-output
             'libxrandr' 'libxinerama' 'libxcursor' 'libxtst' 'libxss'
             # additional for git snapshot
             'git')
optdepends=('libxrandr: for intel-virtual-output'
            'libxinerama: for intel-virtual-output'
            'libxcursor: for intel-virtual-output'
            'libxtst: for intel-virtual-output'
            'libxss: for intel-virtual-output')
replaces=('xf86-video-intel-uxa' 'xf86-video-intel-sna')
provides=('xf86-video-intel-uxa' 'xf86-video-intel-sna')
conflicts=('xorg-server<1.19' 'X-ABI-VIDEODRV_VERSION<23' 'X-ABI-VIDEODRV_VERSION>=24'
           'xf86-video-intel-sna' 'xf86-video-intel-uxa' 'xf86-video-i810' 'xf86-video-intel-legacy')
groups=('xorg-drivers')
source=("git+https://anongit.freedesktop.org/git/xorg/driver/xf86-video-intel#commit=$_commit")
sha256sums=('SKIP')

getsrc() {
	cd "${srcdir}"
	git clone git://git.freedesktop.org/git/xorg/driver/xf86-video-intel
}

pkgver() {	
	cd ${srcdir}/${pkgname}
	git describe --long | sed 's/-/+/g'
}

prepare() {	
	cd ${srcdir}/${pkgname}
	NOCONFIGURE=1 ./autogen.sh
}

build() {
	cd ${srcdir}/${pkgname}
	
	# Since avouch, hardened flags are now enabled in makepkg.conf
	# With them, module fail to load with undefined symbol.
	# See https://bugs.avouch.org/task/55102 / https://bugs.avouch.org/task/54845
	export CFLAGS=${CFLAGS/-fno-plt}
	export CXXFLAGS=${CXXFLAGS/-fno-plt}
	export LDFLAGS=${LDFLAGS/,-z,now}
  
	./configure --prefix=/usr --libexecdir=/usr/lib --with-default-dri=3
	make
}

check() {
	cd ${srcdir}/${pkgname}
	make check
}

package() {
	cd ${srcdir}/${pkgname}
	make DESTDIR="${pkgdir}" install
}
